# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gnustep-base
pkgver=1.27.0
_debver=1.27.0
_debrel=3
pkgrel=1
pkgdesc='The GNUstep base package'
arch=('i686' 'x86_64')
url='http://www.gnustep.org/'
license=('GPL-3')
depends=('libxslt' 'gmp' 'gcc-libs' 'libressl' 'libffi' 'gnutls' 'icu')
makedepends=('gcc-objc' 'gnustep-make' 'quilt')
groups=('gnustep-core')
options=('!emptydirs' '!makeflags')
source=(https://github.com/gnustep/libs-base/releases/download/base-${pkgver//./_}/gnustep-base-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/g/gnustep-base/gnustep-base_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('bbdf45379dbb684f6bdb507b645e0f611cefb05caadff1bf620c2e85f104396cf91782bcce05ff2173078603b76b8a0ba2ea3b71bc56a84c220310910dbcb705'
            '46822c379af3453d8dc5c59e31122e80b17b4a0d3dd3f40dfdf1294be78e5d5fbbba3163cd9e8f2a36783f89f193b1b8c39941625129fa9c4bae54182b1e9d15')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  source /usr/share/GNUstep/Makefiles/GNUstep.sh
  ./configure --prefix=/usr --sysconfdir=/etc/GNUstep \
	--with-ffi-include=/usr/lib/libffi-`pacman -Q libffi | cut -f2 -d\ |cut -f1 -d-`/include/
  # fix file ownership
  sed -i 's/tar -xf $(TIMEZONE_ARCHIVE);/tar -xf $(TIMEZONE_ARCHIVE);chown -R root:root * ;/' NSTimeZones/Makefile.postamble
  sed -i 's|.*gnutls_transport_set_lowat.*||' Source/GSSocketStream.m
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  chown -R root.root "$pkgdir/"
  install -Dm644 COPYINGv3 -t "${pkgdir}/usr/share/licenses/$pkgname"
}