# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gmtp
pkgver=1.3.11
_debver=$pkgver
_debrel=3.1
pkgrel=1
pkgdesc="A simple audioplayer client for MTP based devices"
arch=('i686' 'x86_64')
url='https://gmtp.sourceforge.net/'
license=('Modified-BSD')
depends=('flac' 'gtk' 'libmtp' 'libid3tag' 'libvorbis')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://sourceforge.net/projects/gmtp/files/gMTP-${pkgver}/${pkgname}-${pkgver}.tar.gz/download"
        "https://deb.debian.org/debian/pool/main/g/gmtp/gmtp_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('af6e56136c227818aab19f9eb0a0ad9f1356b24e8a8aa44d600326d632bfcb0dc2794a7c28809f2de2016a52045c1cc5c2bdae0391a0a970ea04e947f920bc95'
            'd61002d31775285a361e4c7b5a1ef59ef982cc05b36bc8e7e0ae835e41105a04a6244b7c51b0252c273991259832fbd68f2c6f63b15660c409fce076684f05d0')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  rm -rf configure
  ./autogen.sh
}

build() {
  cd "${pkgname}-${pkgver}"
  export GLIB_COMPILE_SCHEMAS="/usr/bin/glib-compile-schemas"
  ./configure \
    --prefix=/usr \
    --disable-schemas-compile
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}