# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=geoip
pkgver=1.6.12
pkgrel=1
pkgdesc="Non-DNS IP-to-country resolver C library & utils"
arch=('i686' 'x86_64')
url="https://www.maxmind.com/app/c"
license=('LGPL-2.1')
depends=('zlib' 'geoip-database')
optdepends=('geoip-database-extra: city/ASN databases (not needed for country lookups)')
makedepends=('autoconf' 'libtool')
options=('!emptydirs')
source=("$pkgname-$pkgver.tar.gz::https://github.com/maxmind/${pkgname}-api-c/archive/v${pkgver}.tar.gz")
sha512sums=('d1ed2dae091548f555cde4d26e4b51ae1e8fbb12ef1695fd95963229d9a1bf241e6f09e5d77b151d51edd0cef78ddef490c6a3f3a70ff122bdd9c0ac5500fc7d')

prepare() {
  cd geoip-api-c-$pkgver
  ./bootstrap
}

build() {
  cd geoip-api-c-$pkgver

  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --sysconfdir=/etc/geoip
  make
}

package() {
  cd geoip-api-c-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim:set ts=2 sw=2 et: