# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gengetopt
pkgver=2.23
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A tool to write command line option parsing code for C programs"
arch=('i686' 'x86_64')
url='https://www.gnu.org/software/gengetopt/gengetopt.html'
license=('GPL-3')
options=('!docs' '!makeflags')
depends=('gcc-libs')
makedepends=('quilt')
source=("https://ftp.gnu.org/gnu/gengetopt/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/g/gengetopt/gengetopt_${_debver}+dfsg1-${_debrel}.debian.tar.xz")
sha512sums=('3749191d35acbeff6680f2a4d0516706a0491053f632aaa44ead7c3a42e56f9870bd7c4a85a1886f2052e17d86a2853e2f65d445e0c9920e41f1dc354f003712'
            '13f95e7210f4350e832815a55de7a15afe0735b4656d947ffc2caec259222ae43114f9a9e1ab699a253592865f96849264b73af3301159de16a2ffd13945f886')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vi
}


build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}