# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=geany-plugins
pkgver=1.38
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="Plugins for Geany"
arch=('i686' 'x86_64')
url='https://plugins.geany.org/'
license=('Simplified-BSD' 'GPL-1' 'GPL-2' 'GPL-3' 'Expat' 'custom:PEG-shorted-Expat')
depends=('ctpl' "geany>=$pkgver" 'gpgme' 'libgit2' 'lua51' 'python' 'vte' 'webkitgtk')
makedepends=('cppcheck' 'intltool' 'quilt')
source=("https://plugins.geany.org/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/g/geany-plugins/geany-plugins_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('360905c9b550266ee8cf05396a46465c3f6614709f413f1bc230a1a0f7e3274ae315f2df50ad1eb44550dd32a29d531d9da677b1ecf316dc48a492394de02461'
            '7bac0d1ef6bdc8a78c24dc30726d2b5f8c951277579cc5647531c494569d3c344a3cf6854b7007b99ac840fda654952e5e178949798b65209187c945935887d1')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/debian-doc-locations.patch || true
    rm -v debian/patches/Drop-bundled-gpgme.m4-to-use-updated-system-gpgme.m4.patch || true

    quilt push -av
  fi

  autoreconf -vfi

  # don't redefine bool
  sed -i 's/typedef unsigned int bool/#include <stdbool.h>/g' \
    pretty-printer/src/PrettyPrinter.h
}

build() {
  cd $pkgname-$pkgver
  export CFLAGS+=' -w'
  export PYTHON=/usr/bin/python
  ./configure --prefix=/usr --libexecdir=/usr/lib
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
  install -Dm644 "${srcdir}/$pkgname-$pkgver/debian/copyright" -t "${pkgdir}/usr/share/licenses/$pkgname"
}