# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gcr
pkgver=3.40.0
pkgrel=3
pkgdesc="A library for bits of crypto UI and parsing"
url='https://gitlab.gnome.org/GNOME/gcr'
arch=('i686' 'x86_64')
license=('LGPL-2.1' 'custom:bzip2' 'GPL-2')
depends=('gtk' 'libgcrypt' 'p11-kit')
makedepends=('gobject-introspection' 'vala' 'libxslt' 'meson')
source=("https://gitlab.gnome.org/GNOME/$pkgname/-/archive/$pkgver/$pkgname-$pkgver.tar.gz"
        "gcr-viewer.sh")
sha512sums=('260238be8cc4e873ba1dde9f2edbf97f4e63490f6c8341100ea4ec5f196a5d6ea7cb7ea5a22fa1f8ad4ed384280fbd72361ff9643744712f876cb0438b223e1c'
            '341a01dea3926ff3c89b4ae583844a54f4e0c3d56d9ac08cbf53349542a5033768e54ee297ddba988da36dd9a4e8780953336bb47fd3d63027eab2100ee61d23')

build() {
  cd $pkgname-$pkgver
  hyperbola-meson build -D gtk_doc=false
  meson compile -C build
}

package() {
  cd $pkgname-$pkgver
  DESTDIR="$pkgdir" meson install -C build

  # gcr wants to lock some memory to prevent swapping out private keys
  # https://bugzilla.gnome.org/show_bug.cgi?id=688161
  if [ "$(uname -o)" = 'GNU/Linux' ]; then
    install -dm '755' "${pkgdir}/usr/libexec/gcr"
    mv "${pkgdir}/usr/bin/gcr-viewer" "${pkgdir}/usr/libexec/gcr"
    install -Dm '755' "${srcdir}/gcr-viewer.sh" "${pkgdir}/usr/bin/gcr-viewer"
  fi

  # remove dbus-1 directory
  rm -r "${pkgdir}/usr/share/dbus-1"

  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}