# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=fuse2
pkgver=2.9.9
_debver=$pkgver
_debrel=5
pkgrel=2
pkgdesc="A library that makes it possible to implement a filesystem in a userspace program."
arch=('i686' 'x86_64')
url='https://github.com/libfuse/libfuse'
license=('GPL-2' 'LGPL-2.1')
replaces=('fuse')
conflicts=('fuse')
depends=('glibc' 'fuse-common')
makedepends=('pkg-config' 'quilt')
options=(!emptydirs)
source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/f/fuse/fuse_$_debver-$_debrel.debian.tar.xz)
sha512sums=('3d82fafd04f2924299bb09d2bb144935fa004a43fb9a6568e2e1cc5a60fded2efa1711029a0d7f12b3e6e4501f7217f2ee3545646d89da8dece083cb390f23e2'
            '059468f639c65277c23944aff27a2d6fa03b3c16ff420d6c24dd1dc6c9924c1686d332b80672b24188a938b53dc998e84ecb8b841b97f90db0dd86438c3b455d')

prepare() {
  cd fuse-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -vfi
}

build() {
  cd fuse-$pkgver

  UDEV_RULES_PATH=/lib/udev/rules.d ./configure --prefix=/usr --bindir=/bin --sbindir=/sbin --enable-lib --enable-util --disable-example
  make
}

package() {
  cd fuse-$pkgver

  make DESTDIR=${pkgdir} install

  for i in COPYING{,.LIB}; do
    install -Dm644 $i ${pkgdir}/usr/share/licenses/${pkgname}/$i
  done

  # move libraries to /lib for FHS compliance
  install -d -m755 ${pkgdir}/lib
  mv ${pkgdir}/usr/lib/lib{fuse.so.${pkgver::1}*,ulockmgr.so.1*} ${pkgdir}/lib
  ln -sf ../../lib/libfuse.so.${pkgver::1} ${pkgdir}/usr/lib/libfuse.so
  ln -sf ../../lib/libulockmgr.so.1 ${pkgdir}/usr/lib/libulockmgr.so

  # Remove init script in wrong path
  # Don't add our own for now, as fusectl fs oopses on 2.6.18
  rm -r ${pkgdir}/etc/init.d

  # remove udev rules (included in udev package}
  rm -rf ${pkgdir}/etc/udev

  # static device nodes are handled by udev
  rm -r ${pkgdir}/dev
}