# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ftgl
pkgver=2.4.0
_debver=2.4.0
_debrel=2
pkgrel=1
pkgdesc='OpenGL library to use arbitrary fonts'
arch=('i686' 'x86_64')
url='https://github.com/frankheckenbach/ftgl'
license=('Expat')
depends=('freetype2' 'glu')
makedepends=('doxygen' 'mesa' 'graphviz' 'quilt')
source=("https://github.com/frankheckenbach/ftgl/archive/refs/tags/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/f/ftgl/ftgl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('5a0d05dbb32952e5aa81d2537d604192ca19710cd57289ae056acc5e3ae6d403d7f0ffc8cf6c1aada6c3c23a8df4a8d0eabb81433036ade810bca1894fdfde54'
            '496fa005ce3febd3fa1efb02487fec60ef3369c06d05ffc0e207d15eda395cbc0a1058e5e797f9c460bbe3d4d8d7be13a0ca4af68955f8296c3df97a1273f703')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi

  printf '%s\n' >>docs/doxygen.cfg.in \
    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
  ./autogen.sh
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr --with-pic --disable-static
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install

  # FS#23283: install missing headers for OpenCascade
  install -Dt "$pkgdir/usr/include/FTGL" -m644 src/FT{Face,Size}.h

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
}