# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=fteqcc
pkgver=3343+svn3400
_debver=$pkgver
_debrel=4
pkgrel=1
pkgdesc="Free and libre FTE QuakeC compiler"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/f/fteqcc/fteqcc_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/f/fteqcc/fteqcc_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('07ba548547f0b80089fb75ead50b1e304569a9930db8b051f8c67b53c472e76a9eceb85b7377d8c4b1f9b11e45473e294884bd08e3b784fdbd0e489c6126a646'
            '85aaa4491f0c2d730bc09654e72f087a7f0d8d00267b1f3b38f0817a68c2cf3b385fa6e7aea8c0eac25886ba377080ff846fd8e531210f91861f16965f656b4e')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  install -Dm755 fteqcc.bin "$pkgdir/usr/bin/$pkgname"
  install -Dm644 debian/$pkgname.1 -t "$pkgdir/usr/share/man/man1"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}