# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=freedroidrpg
pkgdesc="Isometric 3D role playing game taking place in the future, on Earth"
pkgver=1.0
pkgrel=1
arch=('i686' 'x86_64')
url='https://gitlab.com/freedroid/freedroid-src'
license=('GPL-2')
depends=('sdl_mixer' 'sdl_image' 'sdl_gfx' 'libogg' 'libvorbis' 'mesa-libgl' 'glu' 'glew')
makedepends=('mesa' 'python')
optdepends=('python' 'espeak')
groups=('games')
source=("https://ftp.osuosl.org/pub/freedroid/freedroidRPG-1.0/freedroidRPG-${pkgver}.tar.gz"
        "fix-build.patch")
sha512sums=('e3cac480e9db02b2991da674ec6357b1d660996f3fa3eeb75f0908ca653a637eeb44239c1cd7540087f27195e460100d08aa022f6812db72387647218c7bcb29'
            '15d7a0478a073d8ecf72fa5592da92fdecbba07599bc602c02468145ad178e91b2f463686cf5ad4b6325520d49f95351bebd959aa044484a23f1d21443f309a8')

prepare() {
  cd $pkgname-${pkgver^^}
  patch -Np1 -i ${srcdir}/fix-build.patch
  autoreconf -v
}

build() {
  cd $pkgname-${pkgver^^}
  export CPPFLAGS="$CPPFLAGS -fcommon -fPIE"
  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datadir=/usr/share/games
  make
}

package() {
  cd $pkgname-${pkgver^^}
  make DESTDIR="${pkgdir}" install

  # fixing wrong folder-locations
  mv ${pkgdir}/usr/share/games/{applications,icons,metainfo} ${pkgdir}/usr/share

  install -Dvm644 COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}
}