# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=(freedoom freedm)
pkgbase=${pkgname[0]}
pkgver=0.13.0
pkgrel=3
pkgdesc="Free and libre game based on the Doom engine"
arch=('any')
url='https://freedoom.github.io/'
license=('Modified-BSD')
depends=('chocolate-doom')
optdepends=('crispy-doom: For enhanced vanilla gameplay-options'
            'prboom-plus: For enhanced vanilla gameplay-options'
            'prboom: For vanilla gameplay-options')
makedepends=('asciidoc' 'deutex' 'python' 'python-pillow')
groups=('games')
source=($pkgbase-$pkgver.tar.gz::https://github.com/$pkgbase/$pkgbase/archive/refs/tags/v$pkgver.tar.gz
        fix-errors.patch
        add-launcher.patch)
sha512sums=('70dd124eee028bbf9aad29b17603c2c4c23e5280219d84a9ffa95417b601cfda33ddf44b6aa991e60194120cfd37110c1c888a5f80d4028e9625377c21f8d7a4'
            'ac63d766a92f2f2a577a7671525eca6c04d34412ccb8e2044aa75d7eb3af7b0ec08b0d776702631c0ada6269612cd106b11c509ed5c2b6655ce8010602427830'
            '0f50ae7172aa2de17a9a33f5d4e4fc9c72113c64ac5690d718b0fcedb8672f66d5a8d12722f42834e60bb9f99750f0c7928b64b44688294d1cad439d271ff9e7')

prepare() {
  cd "$pkgbase-$pkgver"
  patch -Np1 -i ${srcdir}/fix-errors.patch
  patch -Np1 -i ${srcdir}/add-launcher.patch
}

build() {
  cd "$pkgbase-$pkgver"
  make
}

package_freedm() {
  cd "$pkgbase-$pkgver"
  make prefix=/usr bindir=/games DESTDIR="$pkgdir" install-freedm
  install -Dm644 COPYING.adoc -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_freedoom() {
  cd "$pkgbase-$pkgver"
  make prefix=/usr bindir=/games DESTDIR="$pkgdir" install-freedoom
  install -Dm644 COPYING.adoc -t "${pkgdir}/usr/share/licenses/$pkgname"
}