# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=foomatic-db-engine
pkgver=4.0.13
_debver=$pkgver
_debrel=5
pkgrel=3
epoch=1
pkgdesc="Foomatic - Foomatic's database engine generates PPD files from the data in Foomatic's XML database. It also contains scripts to directly generate print queues and handle jobs."
url='https://wiki.linuxfoundation.org/openprinting/database/foomatic'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('perl' 'libxml2' "cups-filters>=1.0.42" 'bash' 'perl-xml-libxml' 'perl-clone' 'perl-dbi')
makedepends=('cups' 'ghostscript' 'a2ps' 'wget' 'perl-xml-libxml' 'foomatic-db' 'quilt')
optdepends=('foomatic-db: linuxprinting.org xml files database to create ppd driver files')
backup=('etc/foomatic/defaultspooler')
source=(https://www.openprinting.org/download/foomatic/$pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/f/foomatic-db-engine/foomatic-db-engine_$_debver-$_debrel.debian.tar.xz)
sha512sums=('da6a0dd9c0d7935d59a4bdd5454c1b7dcb81508f17a98ebfb9fd50fb6b5ed593f4b226715030f22c082c5328c7f7e99d775eeadcb444db5c8ad1441a11a179bf'
            'f790709548529d6490e280c8242c3e20582d3099a74def83b4af36cd85a5c113294111ad978be88217e0b090256cf5844858f24825b4eb19b8b8ea274fa05aff')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  export LIB_CUPS="/usr/libexec/cups"
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  eval `perl -V:archname`
  make DESTDIR=${pkgdir} \
       INSTALLARCHLIB=/usr/lib/perl5/ \
       INSTALLSITELIB=/usr/lib/perl5/ \
       INSTALLSITEARCH=/usr/lib/perl5/ install

  # preset default spooler
  echo cups > ${pkgdir}/etc/foomatic/defaultspooler
  # add some docs
  install -Dm644 USAGE ${pkgdir}/usr/share/doc/${pkgname}/USAGE
  install -Dm644 README ${pkgdir}/usr/share/doc/${pkgname}/README

  # license
  install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING

  # cleanup
  rm -rf ${pkgdir}/usr/lib/perl5/vendor_perl/auto #Foomatic/
}