# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=flac
pkgname=('flac' 'flac-doc')
pkgver=1.3.3
_debver=1.3.3
_debrel=2
pkgrel=1
pkgdesc='Free Lossless Audio Codec'
url='https://xiph.org/flac/'
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('gcc-libs' 'libogg')
makedepends=('nasm' 'doxygen' 'quilt')
source=(https://downloads.xiph.org/releases/flac/${pkgbase}-${pkgver}.tar.xz
        https://deb.debian.org/debian/pool/main/f/flac/flac_$_debver-$_debrel.debian.tar.xz)
sha512sums=('d6417e14fab0c41b2df369e5e39ce62a5f588e491af4d465b0162f74e171e5549b2f061867f344bfbf8aaccd246bf5f2acd697e532a2c7901c920c69429b1a28'
            '1e0bcbed23a121db60236bafaeeb2aad53d3870d0b8b6120281493976fbbf12a2af37bd419b27c3eae3e5799b6fdd8268a7429bcba535265a72334b023c7e241')

prepare() {
  cd ${pkgbase}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd ${pkgbase}-${pkgver}
  ./configure \
    --prefix=/usr \
    --disable-sse
  make
}

check() {
  cd ${pkgbase}-${pkgver}
  make check
}

package_flac() {
  options=('!docs')

  cd ${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING.LGPL -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_flac-doc() {
  pkgdesc+=' documentation'
  depends=('flac')
  license=('FDL-1.2')

  cd ${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" -C doc install
  sed -i "s|${srcdir}/${pkgbase}-${pkgver}|/usr|" "${pkgdir}/usr/share/doc/${pkgbase}/FLAC.tag"
  install -Dm 644 COPYING.FDL -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: