# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=espeak
pkgver=1.48.15
_debver=1.48.15
_debrel=2
pkgrel=1
epoch=1
pkgdesc='Text to Speech engine for English, with support for other languages'
arch=('i686' 'x86_64')
url='http://espeak.sourceforge.net/'
license=('GPL-3')
depends=('portaudio')
makedepends=('quilt')
options=('!emptydirs')
source=("https://deb.debian.org/debian/pool/main/e/espeak/espeak_${pkgver}+dfsg.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/e/espeak/espeak_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('1b51cd9115af322d67ebf5772873d5495ac144d862dddacfb2fe0192f6d74aa580e50d425d18df38c855996a94607c42e6be536e13dc74e89ac82473b9696ec0'
            '736c5a36d28cc5717c976d3616c88d57f40136023ef922ecb87ffdebf85714a9c7a30752529f5d5071ec15907edec90ea4c60fccfefaee17acd1fe488598761e')

prepare() {
  mv  "$pkgname-$pkgver+dfsg" "$pkgname-$pkgver"

  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian ./

    # Doesn't apply
    rm -v debian/patches/sonic || true

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver/src"

  cp portaudio19.h portaudio.h
  make CXXFLAGS="$CXXFLAGS -w -std=c++98" AUDIO=portaudio
}

package() {
  cd "$pkgname-$pkgver/src"

  make DESTDIR="$pkgdir" install
  chmod 644 "$pkgdir/usr/lib/libespeak.a"

  install -Dm644 "${srcdir}/$pkgname-$pkgver/License.txt" -t ${pkgdir}/usr/share/licenses/${pkgname}/
}