# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=enet
pkgver=1.3.17
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="A relatively thin, simple and robust network communication layer on top of UDP"
arch=('i686' 'x86_64')
url='http://enet.bespin.org/'
license=('Expat')
depends=('glibc')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/e/enet/enet_${pkgver}+ds.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/e/enet/enet_${_debver}+ds-${_debrel}.debian.tar.xz")
sha512sums=('c2c8d1361ec035bb8c3c88803a331994ac1e0e37db13f5f6c2f2a1ec146edd71f8d2c770ba1fb6d13ecc9c85204cc993cd917e0225989e93214b1ce0954aa0cd'
            '1ee02ae658b2ef19a845d49ec92dd5779e52ba8368e897f655f0a5aeb1ffe8ca84870d9af412c5aac79bfabaeb1d78ae767f633fd926a9f021aa005225b82e9b')

prepare() {
  mv "${pkgname}-${pkgver}+ds" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}