# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=eigen
pkgver=3.3.9
pkgrel=1
pkgdesc="Lightweight C++ template library for vector and matrix math, a.k.a. linear algebra."
arch=('any')
url='https://eigen.tuxfamily.org'
license=('LGPL-2.1')
makedepends=('cmake' 'freeglut' 'gcc-fortran' 'fftw' 'boost')
source=(https://gitlab.com/libeigen/eigen/-/archive/$pkgver/$pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/e/eigen3/eigen3_3.3.9-2.debian.tar.xz)
sha512sums=('16244cc89f2e1879543232b965cbf653b3ccf10e967c8c437a41e27d8320392bdf584d8c24b8a97406ab7d1481d5154da74e0702ec1334ae6a46de83f4573a46'
            'ac5c45bbcb2603047fa98abdf8da0cb439d6f20de0ba1b9155eddea80a4a1c028d0bea4b257043717768140655ab52be980ae997d51faee983168201195927fc')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  # install custom licenses
  install -Dm644 $pkgname-$pkgver/COPYING.* -t "$pkgdir/usr/share/licenses/$pkgname"
}