# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on pahole package

pkgname=dwarves
pkgver=1.20
_debver=1.20
_debrel=1
pkgrel=1
pkgdesc="Set of advanced DWARF utilities"
url="https://git.kernel.org/pub/scm/devel/pahole/pahole.git"
arch=(i686 x86_64)
license=(GPL-2)
depends=(libbpf libelf python)
makedepends=(cmake ninja quilt)
source=(https://deb.debian.org/debian/pool/main/d/dwarves-dfsg/dwarves-dfsg_1.20.orig.tar.xz
        https://deb.debian.org/debian/pool/main/d/dwarves-dfsg/dwarves-dfsg_$_debver-$_debrel.debian.tar.xz
        python.patch)
sha512sums=('306bb74c498527a5a9bdae4d304e90511336cab627d9acad5237d93cbb48efe11dbca4418c540fa03e3ecdd168ce224cabe9fd2f6fbb50520d0dd17741c80817'
            '7495bee9e58add6fb7e44152d21e7432e696dab5c619fb4b008fdf674d2b90667af7ad0e321fbb4d51450aac85f8cac38ad441f53a19673921d5f3a5eeda24f8'
            '80d067c6505424473084526bae8a60a7f1475ec49b29515a5fbcc14a19f6ca5653d2e833aca0306e9fa2c20a63eba6914885f54313d3e58a26cd2bb04ee1b662')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # https://bugs.archlinux.org/task/70013
  patch -p1 -i ../python.patch
}

build() {
  CFLAGS+=" $CPPFLAGS"
  cmake -S $pkgname-$pkgver -B build -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_MODULE_PATH=/usr/lib/cmake \
    -DLIBBPF_EMBEDDED=OFF \
    -D__LIB=lib
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  export PYTHONHASHSEED=0
  python -m compileall -d / "$pkgdir"
  python -O -m compileall -d / "$pkgdir"

  install -Dm644 $pkgname-$pkgver/COPYING -t $pkgdir/usr/share/licenses/$pkgname
}

# vim:set sw=2 et: