# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dvdbackup
pkgver=0.4.2
_debver=$pkgver
_debrel=4.1
pkgrel=2
pkgdesc="Tool to rip video DVDs from the command line"
arch=('i686' 'x86_64')
url='https://dvdbackup.sourceforge.net'
license=('GPL-3')
depends=('libdvdread' 'libdvdcss')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/$pkgname/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/d/dvdbackup/dvdbackup_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('df9abb2ca0b8a7cd7855ddff94dae249b06b2ec0ee42f3e9c53aa46aebd9885bdf26dacecbd4a20ff5f642ea10c0c64b811d25c23802c8a2b1489281900fbe0d'
            'd505b24d34d5ff42934f46870aad362ee7faf6987a0ddde51e9e629d5910d8fbd41ec2d859c886ee57fbd1898d6dbb09a4cc58c94f508d63c8193c04ac3675e1')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}