# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=docbook-to-man
pkgver=2.0.0
_debver=$pkgver
_debrel=45
pkgrel=1
pkgdesc="Batch converter from DocBook SGML to nroff/troff man macros."
arch=('i686' 'x86_64')
url='http://www.oasis-open.org/docbook/tools/dtm/'
license=('Expat' 'GPL-2')
depends=('opensp')
makedepends=('quilt')
source=("https://deb.debian.org/debian/pool/main/d/docbook-to-man/docbook-to-man_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/d/docbook-to-man/docbook-to-man_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('1aa28a4c2622b0b22eaf68773cd4b839f7ab09b5d44118726f1b815b026a15b7eb2e04ad02c7465296e2fba5472648a608d4cba7c9f9500acd7d8b19763a3a6a'
            'e0fb52e00b3da80258c68ff17b7002c0734d9b29da75e805ac66f9af38abf1a585a5a9960cc2acf621e27650d687de4c2952ea97bf80f7502d2023e40631ddc1')

prepare() {
  mv "$pkgname-$pkgver.orig" "$pkgname-$pkgver"
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0009-remove-sp-dependency.patch || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  make ROOT="$pkgdir/usr/"
}

package() {
  cd $pkgname-$pkgver
  install -d "$pkgdir"/usr/{bin,share,share/sgml/transpec}
  make ROOT="$pkgdir/usr/" install
  install -Dm644 debian/copyright -t "$pkgdir"/usr/share/licenses/$pkgname
}