# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dmidecode
pkgver=3.3
_debver=3.3
_debrel=3
pkgrel=1
pkgdesc="Desktop Management Interface table related utilities"
arch=('i686' 'x86_64')
url="https://www.nongnu.org/dmidecode"
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
source=("https://download.savannah.nongnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.sig}
        "https://deb.debian.org/debian/pool/main/d/dmidecode/dmidecode_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('dc77f40a7898011cea1b747d4677be2fbe8f52ec6ac460a5656de2f3389eca83bc416d6494acbe759971b5afce37b78f21ab55c34d62b1105b800e31566d1d22'
            'SKIP'
            '1dd387f26fc99780b0c95d773eaf6da48873b80327871f2e8a11ecba3c95a013e53a469e91a20a3b53f118cfc5a5b60c14d2b2ea8ad84581d206c709e281366d')
validpgpkeys=('90DFD6523C57373D81F63D19865688D038F02FC8') # Jean Delvare <khali@linux-fr.org>

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-hurd.patch || true

    quilt push -av
  fi
}


build() {
  cd ${pkgname}-${pkgver}
  make prefix=/usr CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
}

package() {
  cd ${pkgname}-${pkgver}
  make prefix=/usr DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}