# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=devil
pkgver=1.8.0
pkgrel=2
pkgdesc="Library for reading several different image formats"
arch=('i686' 'x86_64')
url="http://openil.sourceforge.net/"
depends=('libpng' 'jasper' 'lcms2' 'libjpeg-turbo')
makedepends=('cmake')
options=('!docs' '!emptydirs')
license=('LGPL-2.1')
source=(https://downloads.sourceforge.net/openil/DevIL-$pkgver.tar.gz
        soversion.patch)
sha512sums=('103fa51f4094af0fe988bf9520e1b9178900f980b72226e64ede60b6b0938a646c670a37372214edb557e492947cd5af5012a3ac906734a5ea83e072f81db583'
            '0ecc93f0236d113c39d8e2acc19eead719a3ba474bf504ba3806830cbfb9c3d2dbe375a9a41bc866fa5e1e738f8bbeff9734b52f90a29b796a4e09baae3846e8')

prepare() {
  cd "${srcdir}/DevIL"

  # Add solib version number to CMakeLists.txt
  # https://github.com/DentonW/DevIL/pull/50
  patch -Np1 -i "${srcdir}/soversion.patch"
}

build() {
  cd "${srcdir}/DevIL/DevIL"

  rm -rf build && mkdir build
  cd build
  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib
  make
}

package() {
  cd "${srcdir}/DevIL/DevIL/build"

  make DESTDIR="$pkgdir" install
  install -Dm644 ../COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}