# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=darkplaces
pkgver=20170829beta1
pkgrel=2
pkgdesc="An advanced, free and libre 3D game engine"
arch=('i686' 'x86_64')
url='https://icculus.org/twilight/darkplaces/'
license=('GPL-2')
install=$pkgname.install
depends=('alsa-lib' 'hicolor-icon-theme' 'libjpeg-turbo' 'libxpm' 'libxxf86vm' 'sdl2' 'mesa-libgl')
groups=('games')
source=("https://icculus.org/twilight/darkplaces/files/darkplacesengine${pkgver}.zip"
        "$pkgname.desktop")
sha512sums=('49ec750199240eb7ba4eae6ede3a3ee85bafef07607b827111fb7846f7283c44a480637a45fd85a33f441ab2f99c44dc105348ea5da04d0397650f1a347cf3e9'
            '327a54479d5823c3e58931326038f1ee3388d1f6df1a0e4e91904092ae1bb9ae439c5d306ef8cee8238c81416a78cf881d2aca7c8cf64ccb0735ecd6825817e9')
noextract=(darkplacesengine$pkgver.zip)

prepare() {
  cd "$srcdir"
  bsdtar -xf darkplacesengine$pkgver.zip darkplacesenginesource$pkgver.zip
  bsdtar -xf darkplacesenginesource$pkgver.zip
  cd "darkplaces"

  # fix a couple options in the Makefile.
  sed -i '1i DP_LINK_TO_LIBJPEG=1' makefile
  sed -i '/(STRIP)/d' makefile.inc
}

build() {
  cd "$srcdir/darkplaces"

  # make sure package is not compiled with -j > 1.
  MAKEFLAGS="${MAKEFLAGS} -j1"
  make OPTIM_RELEASE="${CFLAGS}" DP_FS_BASEDIR=/usr/share/games/quake release
}

package() {
  cd $srcdir/darkplaces
  install -d $pkgdir/usr/games
  install -m755 darkplaces-{dedicated,glx,sdl} $pkgdir/usr/games

  for i in 16 24 32 48 64 72; do
    install -Dm644 darkplaces${i}x${i}.png $pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/darkplaces.png
  done
  install -Dm644 $srcdir/$pkgname.desktop -t $pkgdir/usr/share/applications

  # prepare empty data-directory
  install -d $pkgdir/usr/share/games/quake
}