# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=('cyrus-sasl')
pkgname=('cyrus-sasl' 'cyrus-sasl-gssapi' 'cyrus-sasl-ldap' 'cyrus-sasl-sql')
pkgver=2.1.27
_debver=$pkgver
_debrel=2.1
pkgrel=3
pkgdesc="Cyrus Simple Authentication Service Layer (SASL) library"
arch=('i686' 'x86_64')
url="https://www.cyrusimap.org/sasl/"
license=('Original-BSD')
options=('!makeflags')
makedepends=('postgresql-libs' 'libldap' 'krb5' 'libressl' 'sqlite' 'quilt')
source=(https://github.com/cyrusimap/cyrus-sasl/releases/download/cyrus-sasl-$pkgver/cyrus-sasl-$pkgver.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/c/cyrus-sasl2/cyrus-sasl2_$_debver+dfsg-$_debrel+deb11u1.debian.tar.xz
        0003-Update-saslauthd.conf-location-in-documentation.patch
	0006-Enable-autoconf-maintainer-mode.patch
        0010-Update-required-libraries-when-ld-as-needed-is-used.patch
        0013-Don-t-use-la-files-for-opening-plugins.patch
        0020-Restore-LIBS-after-checking-gss_inquire_sec_context_.patch
        0022-Fix-keytab-option-for-MIT-Kerberos.patch
        0032-Add-with_pgsql-include-postgresql-to-include-path.patch
        gdbm-errno.patch
        saslauthd.confd
        saslauthd.initd)
sha512sums=('d11549a99b3b06af79fc62d5478dba3305d7e7cc0824f4b91f0d2638daafbe940623eab235f85af9be38dcf5d42fc131db531c177040a85187aee5096b8df63b'
            'SKIP'
            '73d70392eb16107d3e84f083dcfeb79abf33413734244748cb7eef24089ed9ad0da60e778b096bdcd134878f28bfd9cd3801f6e707ed03d6b9338407bdbe6972'
            'ccd8a9e06578a4811d24c883e45d4dc51a35c2875851ab372113d612d9e52470faa08748e8c27b5bdfe8aee47caf91c40b04211ddff43087f7e0b43c5819f783'
            '852791cadfb1bdde948814185f307bbada781f8562319c90fea7d5248d545432e6103cb113dfc89525c8a74cc30f1b8686e52a8b658efad9738609473a1dbc74'
            'e44c7bc90b9140f3cc442c2155ac89c13b9bd5422c2d8ac1fddf83b64c312ba621322b32639c4f517aa05c78d6a1cd94dc257892e706844f6be095a3863127d7'
            'dc056e74d895e81494a39ba05ec97623f9bbd7b61f44ff0bae8cb847c8e5882d47d384d0da429ab0de2c2bd4530b6ead2e595d6dd17960bfc1aa3d2ded0a823d'
            'cf747487df71c66d22e78ec3ca658f2f2752b224851d23070374119378e4a738996eb8256583437f92f34e63488c5a205a8a37deeb8d98bdbe0a679cbb00d8fb'
            '1364657633a4aa2944415477108d38acc94f37ad92470205fb36b7307e4924b02d0029bab4bae4439a2d13cb57d9209974dbf7b55f4cde2448571ccec8d62f9b'
            '48f61c050e8b372b994bc2d56d04a29a07922d2f149ad890f6895e6ec0ed0e7cd2069e63a6445cfe87be23ae95b9ff259b3d70f64a449ceb420587ef21e2f57b'
            'd7dfdf520d16a79f265708d1c6938bd24bd26b9a0ff9b7fcbfc95c494af7f44220080bd3f79d0486bb6fc30b4a9a269adb7836bc593eacca99a1ef549ce58a9e'
            'fe7102c67b9cf8438cabb1d4dc69d0a173b6ec3134c8ea5c60551d9fd1daaa20664b8ea197f8e118e224cb0686b2e83c51d31d785106d15d0758b95ef89c90e2'
            '1d5942a94ffbc15774443d60a88d4c89c7c3c6ea68b041d304f0110f6ec3aa2a812f59021cddc78de6f51a25bb00955e4e56d769e766a9d856f13774dd37ce83')
validpgpkeys=('829F339F8C296FE80F409D93E3D7C118C7B9F46A') # Partha Susarla <mail@spartha.org>

prepare() {
  cd cyrus-sasl-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-Make-the-libsasl2-symbols-versioned.patch || true
    rm -v debian/patches/0002-Use-etc-sasldb2-instead-of-.-sasldb-in-the-testsuite.patch || true
    rm -v debian/patches/0004-Include-dbconverter-2-in-sbin_PROGRAMS-and-set-defau.patch || true
    rm -v debian/patches/0017-Just-completely-remove-libobj-from-autotools-files.patch || true
    rm -v debian/patches/0018-Temporary-multiarch-fixes.patch || true
    rm -v debian/patches/0019-Add-reference-to-LDAP_SASLAUTHD-file-to-the-saslauth.patch || true
    rm -v debian/patches/0025-Revert-upstream-soname-bump.patch || true
    rm -v debian/patches/0033-cross.patch || true

    quilt push -av
  else
    patch -Np1 -i $srcdir/0003-Update-saslauthd.conf-location-in-documentation.patch
    patch -Np1 -i $srcdir/0006-Enable-autoconf-maintainer-mode.patch
    patch -Np1 -i $srcdir/0010-Update-required-libraries-when-ld-as-needed-is-used.patch
    patch -Np1 -i $srcdir/0013-Don-t-use-la-files-for-opening-plugins.patch
    patch -Np1 -i $srcdir/0020-Restore-LIBS-after-checking-gss_inquire_sec_context_.patch
    patch -Np1 -i $srcdir/0022-Fix-keytab-option-for-MIT-Kerberos.patch
    patch -Np1 -i $srcdir/0032-Add-with_pgsql-include-postgresql-to-include-path.patch
  fi

  patch -Np1 -i $srcdir/gdbm-errno.patch

  cp -a saslauthd/saslauthd.mdoc saslauthd/saslauthd.8
  rm -f config/config.guess config/config.sub
  rm -f config/ltconfig config/ltmain.sh config/libtool.m4
  rm -fr autom4te.cache

  libtoolize -c
  aclocal -I config
  automake -a -c
  autoheader
  autoconf
}

build() {
  export CFLAGS="$CFLAGS -fPIC"
  cd cyrus-sasl-$pkgver

  ./configure --prefix=/usr \
      --mandir=/usr/share/man \
      --infodir=/usr/share/info \
      --disable-static \
      --enable-shared \
      --enable-alwaystrue \
      --enable-checkapop \
      --enable-cram \
      --enable-digest \
      --disable-otp \
      --disable-srp \
      --disable-srp-setpass \
      --disable-krb4 \
      --enable-gssapi \
      --enable-auth-sasldb \
      --enable-plain \
      --enable-anon \
      --enable-login \
      --enable-ntlm \
      --disable-passdss \
      --enable-sql \
      --without-mysql \
      --with-pgsql=/usr/lib \
      --with-sqlite3=/usr/lib \
      --enable-ldapdb \
      --disable-macos-framework \
      --without-pam \
      --with-saslauthd=/var/run/saslauthd \
      --with-ldap \
      --with-dblib=gdbm \
      --with-configdir=/etc/sasl2:/etc/sasl:/usr/lib/sasl2 \
      --sysconfdir=/etc \
      --with-devrandom=/dev/urandom
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package_cyrus-sasl() {
  depends=("libsasl=${pkgver}" 'krb5')
  pkgdesc="Cyrus saslauthd SASL authentication daemon"
  backup=('etc/conf.d/saslauthd')

  cd cyrus-sasl-$pkgver/saslauthd
  make DESTDIR="${pkgdir}" install
  install -Dm644 "${srcdir}/saslauthd.confd" "${pkgdir}/etc/conf.d/saslauthd"
  install -Dm755 "${srcdir}/saslauthd.initd" "${pkgdir}/etc/init.d/saslauthd"

  install -Dm644 ../COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

package_cyrus-sasl-gssapi() {
  pkgdesc="GSSAPI authentication mechanism for Cyrus SASL"
  depends=("libsasl=${pkgver}" 'krb5')
  replaces=('cyrus-sasl-plugins')

  cd cyrus-sasl-$pkgver/plugins
  install -m755 -d "${pkgdir}/usr/lib/sasl2"
  cp -a .libs/libgssapiv2.so* "${pkgdir}/usr/lib/sasl2/"
  cp -a .libs/libgs2.so* "${pkgdir}/usr/lib/sasl2/"

  install -Dm644 ../COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

package_cyrus-sasl-ldap() {
  pkgdesc="ldapdb auxprop module for Cyrus SASL"
  depends=("libsasl=${pkgver}" 'libldap')
  replaces=('cyrus-sasl-plugins')

  cd cyrus-sasl-$pkgver/plugins
  install -m755 -d "${pkgdir}/usr/lib/sasl2"
  cp -a .libs/libldapdb.so* "${pkgdir}/usr/lib/sasl2/"

  install -Dm644 ../COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

package_cyrus-sasl-sql() {
  pkgdesc="SQL auxprop module for Cyrus SASL"
  depends=("libsasl=${pkgver}" 'postgresql-libs' 'sqlite')
  replaces=('cyrus-sasl-plugins')

  cd cyrus-sasl-$pkgver/plugins
  install -m755 -d "${pkgdir}/usr/lib/sasl2"
  cp -a .libs/libsql.so* "${pkgdir}/usr/lib/sasl2/"

  install -Dm644 ../COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}