# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=csh
pkgver=20110502
_debver=$pkgver
_debrel=6
pkgrel=1
pkgdesc="Shell with C-like syntax"
arch=('i686' 'x86_64')
url='https://www.openbsd.org/cgi-bin/cvsweb/src/bin/csh/'
license=('Modified-BSD')
install=$pkgname.install
depends=('libbsd')
makedepends=('quilt' 'bmake')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/c/csh/csh_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/csh/csh_${_debver}-${_debrel}.debian.tar.xz"
        "fix-build.patch")
sha512sums=('17935f8857a5e286c04c8ff08a788224fcb9ab7b29439ad4f0fdeaafe8bd6331ab8ef2a2a2b1b70613580f2d7fce03c97ffe0364ec01a5cca9ade9cc4ae55b73'
            '67a953fafee227494444e458853843e8a195287dc97b5f22eae78e3dea33800f0342fe5985ad685a93dc435d9592a8c05ec890afbecedca9294dfc21d9fb4eb3'
            '88db21017b3255ad6a606ac04f4b6e9115358a68e905b0baed503d813c0bca288e76425ec4e5332ef842520736b4ae4e74da3cb5edc6543bc6a26a6cad98abc3')

prepare() {
  mv "${pkgname}-${pkgver}.orig" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/fix-build.patch
}

build() {
  cd "${pkgname}-${pkgver}"
  bmake
}

package() {
  cd "${pkgname}-${pkgver}"
  bmake DESTDIR="$pkgdir" install
  mv "$pkgdir/usr/bin" "$pkgdir/bin"

  # manpage
  rm -rf "$pkgdir/usr/share/man"
  install -Dm 644 -p csh.1 -t "$pkgdir/usr/share/man/man1"

  # license
  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}