# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=clutter
pkgver=1.26.4
_debver=1.26.4+dfsg
_debrel=2
pkgrel=1
pkgdesc="A toolkit for creating fast, portable, compelling dynamic UIs"
url="https://blogs.gnome.org/clutter/"
arch=(i686 x86_64)
license=(LGPL-2.1)
depends=(gtk cogl)
makedepends=(gobject-introspection quilt)
source=(https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz
        https://deb.debian.org/debian/pool/main/c/clutter-1.0/clutter-1.0_$_debver-$_debrel.debian.tar.xz)
sha512sums=('6d43ac09df7671fa2bda74d1231166e8331f3ef1dbe0d167225033b3ddae7377d1062db81b73fc498c2e9f0db467bf4febb7306a6f40c9ef0266dac2a397f43a'
            '9f17bbb73e7b66a5dc23cf603950dbd94cf2ba116e216f360f59dc6121453a9dfb3bd90cacb49e6da755c1d408f5a149bd87e07fff554c1b13108e08481308b6')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
    --enable-introspection \
    --enable-egl-backend \
    --enable-gdk-backend \
    --disable-wayland-backend \
    --enable-x11-backend \
    --enable-evdev-input \
    --disable-wayland-compositor \
    --disable-gtk-doc

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}

# vim:set sw=2 et: