# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cifs-utils
pkgver=7.0
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="CIFS filesystem user-space tools"
arch=('i686' 'x86_64')
url='https://wiki.samba.org/index.php/LinuxCIFS_utils'
license=('GPL-3')
depends=('libcap-ng' 'keyutils' 'krb5' 'talloc' 'libwbclient')
makedepends=('python-docutils' 'quilt')
source=("https://download.samba.org/pub/linux-cifs/$pkgname/$pkgname-$pkgver.tar.bz2"{,.asc}
	"https://deb.debian.org/debian/pool/main/c/cifs-utils/cifs-utils_$_debver-$_debrel.debian.tar.xz")
sha512sums=('4c57741af0c4567a78f352c73caca998881666a5ed36536275cfa775efd66ff1a44ebe539a8ed96c409c5b08a1378266964ce667a27e9fc7f2d43999c63dd0eb'
            'SKIP'
            '29a052e740c166ba2563cc59395461f36086fd17b604d2cfda7e76782774861cacc49387f35da7e0471b6e9a290f7581faeb302536cbd8c1f7a3ca5530e3b442')
validpgpkeys=('C699981A31F338706C817650DF5BA9D30642D5A0') #cifs-utils Distribution Verification Key <cifs-utils@samba.org>

prepare() {
  # fix install to honor DESTDIR
  sed -e 's|cd \$(ROOTSBINDIR)|cd $(DESTDIR)$(ROOTSBINDIR)|g' -i $pkgname-$pkgver/Makefile.am

  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --disable-systemd
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" ROOTSBINDIR="/usr/sbin" install
  mkdir -p "$pkgdir"/etc/request-key.d
  install -m 644 contrib/request-key.d/cifs.idmap.conf "$pkgdir"/etc/request-key.d
  install -m 644 contrib/request-key.d/cifs.spnego.conf "$pkgdir"/etc/request-key.d

  # set mount.cifs uid, to enable none root mounting from fstab
  chmod +s "$pkgdir"/usr/sbin/mount.cifs

  mkdir -p "$pkgdir"/etc/cifs-utils
  ln -s /usr/lib/cifs-utils/idmapwb.so "${pkgdir}"/etc/cifs-utils/idmap-plugin

  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}