# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=chocolate-doom
pkgdesc="Historically-accurate 3D game-engine"
pkgver=3.1.0
pkgrel=2
arch=('i686' 'x86_64')
url='https://www.chocolate-doom.org/'
license=('GPL-2')
install=$pkgname.install
depends=('libpng' 'libsamplerate' 'sdl2_mixer' 'sdl2_net')
makedepends=('python')
optdepends=('freedm: Free and libre deathmatch game'
            'freedoom: Free and libre action-games'
            'blasphemer: Free and libre dark-fantasy game')
groups=('games')
source=("https://github.com/${pkgname}/${pkgname}/archive/refs/tags/${pkgname}-${pkgver}.tar.gz"
        "chocolate-heretic")
sha512sums=('17f65c6f4a48dd1b0aa71bdf495d1036602739f1955d64f7de46157fce912ab4e4344a0f7ad073980f50d67e34f9f5e84402e7f2142cd6364453b71c8d5c2592'
            '7ae8de11f633774f57fe3c433dcdbc38483d27fcdfc208191b069dbc6966cf07ea65d8c42711a24ba14d961eb3bed234597afe9d5491a2af181b0613d14e7564')

prepare() {
  mv "${pkgname}-${pkgname}-${pkgver}" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  ./autogen.sh
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr \
    --bindir=/usr/games
  make
}

package() {
  cd "${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
  mv "${pkgdir}"/usr/games/chocolate-heretic "${pkgdir}"/usr/games/heretic
  install -Dm755 "${srcdir}"/chocolate-heretic -t "${pkgdir}"/usr/games
  install -dm 755 "${pkgdir}"/usr/share/games/doom

  # removing content for accessing non-free data
  rm "${pkgdir}"/usr/games/{chocolate-hexen*,chocolate-strife*}
  rm "${pkgdir}"/usr/share/applications/{org.chocolate_doom.Hexen*,org.chocolate_doom.Strife*}
  rm "${pkgdir}"/usr/share/bash-completion/completions/{chocolate-hexen*,chocolate-strife*}
  rm -rf "${pkgdir}"/usr/share/doc/{chocolate-hexen*,chocolate-strife*}
  rm "${pkgdir}"/usr/share/man/man5/{chocolate-hexen*,chocolate-strife*}
  rm "${pkgdir}"/usr/share/man/man5/{hexen*,strife*}
  rm "${pkgdir}"/usr/share/man/man6/{chocolate-hexen*,chocolate-strife*}
  rm "${pkgdir}"/usr/share/metainfo/{org.chocolate_doom.Hexen,org.chocolate_doom.Strife}.metainfo.xml

  # license
  install -Dm644 COPYING.md -t "${pkgdir}/usr/share/licenses/$pkgname"
}