# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=cbatticon
pkgname=('cbatticon' 'cbatticon-gtk2')
pkgver=1.6.9
pkgrel=2
pkgdesc="Lightweight battery icon for the system tray"
arch=('i686' 'x86_64')
url='https://github.com/valr/cbatticon'
license=('GPL-2')
makedepends=('gtk' 'gtk2' 'gettext-tiny')
source=("${pkgbase}-${pkgver}.tar.gz::https://github.com/valr/cbatticon/archive/${pkgver}.tar.gz"
        "$pkgbase.desktop")
sha512sums=('bbaef2b24eddc52e3ad63033e063620960aa791f6bcb06cd1b981ca2a4f38450ee2c2177426b171ece2b5fff0db8f360bd9ca9ef1a3351ec9ad1f5ea34f925f4'
            '17f819f297629b792076b6803903b858f8989e8908be237a4fd6000a1d6573e8c52fa51330c56729da97375d3a199733dfe1899297611ae40e6a090d2a0136c2')

build() {
  # GTK+ 2 version
  [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
  cd gtk2
  make WITH_NOTIFY=0 WITH_GTK3=0

  cd "$srcdir"
  # GTK+ 3 version
  [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
  cd gtk3
  make WITH_NOTIFY=0 WITH_GTK3=1
}

package_cbatticon-gtk2() {
  depends=('gtk2')
  conflicts=('cbatticon')

  cd "gtk2"
  make PREFIX="$pkgdir/usr" install
  install -Dm644 "${srcdir}/$pkgbase.desktop" -t "${pkgdir}/usr/share/applications/"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_cbatticon() {
  pkgdesc+=' (GTK+ 3 version)'
  depends=('gtk')
  conflicts=('cbatticon-gtk2')

  cd "gtk3"
  make PREFIX="$pkgdir/usr" install
  install -Dm644 "${srcdir}/$pkgbase.desktop" -t "${pkgdir}/usr/share/applications/"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}