# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cairo
pkgver=1.16.0
_debver=$pkgver
_debrel=4
pkgrel=2
pkgdesc="2D graphics library with support for multiple output devices"
url='https://cairographics.org/'
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('libpng' 'libxrender' 'libxext' 'fontconfig' 'pixman' 'glib2' 'lzo')
makedepends=('librsvg-legacy' 'poppler-glib' 'libspectre' 'quilt')
source=(https://www.cairographics.org/releases/$pkgname-$pkgver.tar.xz
        https://deb.debian.org/debian/pool/main/c/cairo/cairo_$_debver-$_debrel.debian.tar.xz
        0001-image-compositor-Remove-the-right-glyph-from-pixman-.patch)
sha512sums=('9eb27c4cf01c0b8b56f2e15e651f6d4e52c99d0005875546405b64f1132aed12fbf84727273f493d84056a13105e065009d89e94a8bfaf2be2649e232b82377f'
            '1f33867329228ac23bddb812d197688eacadc3d8ae8a8f8304ae9c0690187d4418cfe85905a8117e0e02570ea3dcc5a7d0d451dfded3b16231368e13f92f67d2'
            '18071c1fb117fa51f7a77886efb66deec4aa5e7fec2a5fecec5ac1447ee04ca773f96aa8f65a0a7ecfd9405835dabb1b54b51fc5eb5d24d0f24d266c21e74236')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/01_build_perf_utils.patch || true
    rm -v debian/patches/02_am-maintainer-mode.patch || true
    rm -v debian/patches/03_export-symbols.patch || true
    rm -v debian/patches/06_hurd-map-noreserve.patch || true

    quilt push -av
  fi

  patch -Np1 -i $srcdir/0001-image-compositor-Remove-the-right-glyph-from-pixman-.patch

  # fix typo
  sed -i 's/have_png/use_png/g' configure.ac

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
        --sysconfdir=/etc \
        --localstatedir=/var \
        --disable-static \
        --disable-gl \
        --enable-tee \
        --enable-svg \
        --enable-ps \
        --enable-pdf \
        --enable-gobject \
        --disable-gtk-doc
  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # we don't support gtk-doc
  rm -rf $pkgdir/usr/share/gtk-doc

  for i in COPYING{,-LGPL-2.1}; do
    install -Dm644 $i $pkgdir/usr/share/licenses/$pkgname/$i
  done
}