# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=bigloo
_pkgver=4.3a
pkgver=${_pkgver/-/_}
pkgrel=1.hyperbola2
pkgdesc="Fast scheme compiler, without avahi and java-environment support and with libressl support"
arch=('i686' 'x86_64')
url="https://www-sop.inria.fr/mimosa/fp/Bigloo/"
license=('GPL-2' 'LGPL-2')
depends=('gmp' 'libressl' 'libunistring')
makedepends=('emacs' 'zip' 'sqlite' 'alsa-lib' 'flac' 'chrpath')
optdepends=('emacs' 'zip' 'sqlite' 'alsa-lib' 'flac')
options=('!makeflags')
source=(ftp://ftp-sop.inria.fr/indes/fp/Bigloo/${pkgname}${_pkgver}.tar.gz
        lgpl-2.0.txt)
sha512sums=('fe2acc232d6cf84fef5ce36aae35baac584b4166d11cf887c60ad1da6c5f8face5ef02f0780e994b48d984fecd7d110637c1e56a219d2e73a214a7dc7c94a600'
            '81ebc009d68bf54a25c6b8fe36d8a4176570258c346a492aa743c567e3e38e3a01be4d8c47eb34eeacf9b5e1e04743bd08483c0935a3de7cd2a69a402ba6fcbc')

elisp_dir=/usr/share/emacs/site-lisp/bigloo

build() {
  cd "${srcdir}/${pkgname}${_pkgver}"
  ./configure --prefix=/usr \
    --enable-ssl \
    --enable-sqlite \
    --lispdir=${elisp_dir} \
    --disable-avahi \
    --enable-flac \
    --disable-gstreamer \
    --mandir=/usr/share/man \
    --infodir=/usr/share/info \
    --docdir=/usr/share/doc/bigloo \
    --jvm=no
  make build compile-bee
}

check() {
  cd "${srcdir}/${pkgname}${_pkgver}"
  make test
}

package() {
  cd "${srcdir}/${pkgname}${_pkgver}"

  make DESTDIR="${pkgdir}" install install-bee
  make -C manuals DESTDIR="${pkgdir}" install-bee

  chmod 644 "${pkgdir}"${elisp_dir}/etc/bass-snap.au \
	"${pkgdir}"${elisp_dir}/images/*

  rm ${pkgdir}/usr/bin/{bglafile,bigloo}.sh

  # Remove references to the build root
  sed -e "s|^BOOTDIR=.*|BOOTDIR=/usr|g" \
      -e "s|^BOOTBINDIR=.*|BOOTBINDIR=/usr/bin|g" \
      -e "s|^BOOTLIBDIR=.*|BOOTLIBDIR=/usr/lib/bigloo/${pkgver}|g" \
      -e "s|^BGLBUILDBINDIR=.*|BGLBUILDBINDIR=/usr/bin|g" \
      -e "s|^BGLBUILDLIBDIR=.*|BGLBUILDLIBDIR=/usr/lib/bigloo/${pkgver}|g" \
      -e "s|^\(BIGLOO=.*\)\.sh|\1|" \
      -e "s|^\(BGL.*=.*\)\.sh|\1|" \
      -i  ${pkgdir}/usr/lib/bigloo/${pkgver}/Makefile.config

  # Install license files
  install -d -m755 ${pkgdir}/usr/share/licenses/${pkgname}
  install -Dm644 COPYING LICENSE ${pkgdir}/usr/share/licenses/${pkgname}
  install -Dm644 ${srcdir}/lgpl-2.0.txt ${pkgdir}/usr/share/licenses/${pkgname}/COPYING.LIB
}