# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=automake-1.11
_realname=automake
pkgver=1.11.6
pkgrel=1
pkgdesc="A GNU tool for automatically creating Makefiles"
arch=('any')
license=('GPL-2')
url='http://www.gnu.org/software/automake'
depends=('perl' 'bash')
makedepends=('autoconf')
provides=("automake=$pkgver")
install=automake.install
source=(ftp://ftp.gnu.org/gnu/${_realname}/${_realname}-${pkgver}.tar.xz
        perl2.6.patch)
sha512sums=('6e4cdf69f07734954f770fd4a7211a8c9dc69fe25a7746bd3c1e01d3139c94cab2900399e87371548833e99687e0d2b59c5e746ab2fdfbc7d47f2c1d439137ba'
            'b64bdfe60aa16289b90e9da8544229fcd61af1bd35fb2aa3447bd666b562c2799345b2b1a2ecc2430bf6a540f26d5c506272eacaf4cb8fd17a0eab04c34af1aa')

prepare() {
  cd ${srcdir}/${_realname}-${pkgver}
  patch -p1 < ../perl2.6.patch
}

build() {
  cd ${srcdir}/${_realname}-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${srcdir}/${_realname}-${pkgver}
  make DESTDIR=${pkgdir} install

  rm -rf "$pkgdir/usr/"{bin/{aclocal,automake},share/{doc,aclocal}}
  rm "$pkgdir/usr/share/man/man1/"{aclocal,automake}.1
  find $pkgdir/usr/share/info -type f -exec rename automake automake-1.11 '{}' ';'

  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}