# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=audiofile
pkgver=0.3.6
_debver=0.3.6
_debrel=5
pkgrel=1
pkgdesc="Silicon Graphics Audio File Library"
arch=('i686' 'x86_64')
url="https://audiofile.68k.org/"
license=('LGPL-2.1')
depends=('gcc-libs' 'alsa-lib' 'flac')
makedepends=('quilt' 'asciidoc')
source=("https://audiofile.68k.org/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/audiofile/audiofile_$_debver-$_debrel.debian.tar.xz")
sha512sums=('f9a1182d93e405c21eba79c5cc40962347bff13f1b3b732d9a396e3d1675297515188bd6eb43033aaa00e9bde74ff4628c1614462456529cabba464f03c1d5fa'
            'de7abf10f8c61dc31b52f61abc0fbb0f95699a2122c4652e43d0c9ad13793e2cdcfd883d85d6d1f911648ceb73f4423b759a8d079e22a717e28b27cc45d1d817')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -vDm 644 {AUTHORS,ChangeLog,NEWS,NOTES,README,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}