# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=audacity-legacy
_realpkgname=audacity
pkgver=2.4.2
_debver=$pkgver
_debrel=5
pkgrel=2
pkgdesc="A free and libre program that lets you manipulate digital audio waveforms (legacy version)"
arch=('i686' 'x86_64')
license=('GPL-2' 'CC-BY-3.0')
provides=('audacity')
conflicts=('audacity')
depends=('expat' 'gcc-libs' 'gdk-pixbuf2' 'glibc' 'libmad'
         'libsoxr' 'portsmf' 'soundtouch' 'vamp-plugin-sdk'
         'twolame' 'wxgtk3')
makedepends=('alsa-lib' 'cmake' 'ffmpeg' 'flac' 'glib2' 'gtk' 'jack' 'lame'
             'libid3tag' 'libogg' 'libsndfile' 'libvorbis' 'lilv' 'lv2' 'portsmf' 'suil'
             'twolame' 'vamp-plugin-sdk' 'git-legacy' 'nasm' 'quilt')
optdepends=('ffmpeg: additional import/export capabilities')
source=("${_realpkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/a/audacity/audacity_${pkgver}~dfsg0.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/a/audacity/audacity_${_debver}~dfsg0-${_debrel}.debian.tar.xz"
        "disable-update-check.patch")
sha512sums=('9f981ac844b86677454c4cbbb1ce1c837ebb56c306eba313c0d9b1add9325d1bd7cd0149a0f5f0f45926d6223d71d7f12f822570c8171a5324f6f05bde147e54'
            '055e49ff2a4058ab5bb3e4d042e7d24af37ff780b6f8d801fa61ad34b47ee9459756b5184ee917fd8744903c26f2ad9b3dd68316f5c2ac1885197b87f53499a6'
            '58a9067ff3bf4800fa9174f55d9a8faf2071b8df49c8d90b6f190f7b5bf5455d969c081b0ae7795845f277af324283e7affbaec96934c1014809a09c74ee8791')

prepare() {
  mv -v "${_realpkgname}-Audacity-${pkgver}" "${_realpkgname}-${pkgver}"
  cd "${_realpkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # remove update-check from menus
  patch -Np1 -i ${srcdir}/disable-update-check.patch
}

build() {
  export WX_CONFIG=wx-config-gtk3
  cmake \
    -S ${_realpkgname}-${pkgver} \
    -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Daudacity_use_sndfile=system \
    -Daudacity_use_ffmpeg=loaded \
    -Daudacity_use_expat=system \
    -Daudacity_use_lame=local \
    -Daudacity_use_portaudio=local \
    -Daudacity_use_midi=local \
    -Daudacity_use_flac=system \
    -Daudacity_use_id3tag=system \
    -Daudacity_use_sbsms=off \
    -Daudacity_use_soundtouch=system \
    -Daudacity_use_twolame=system \
    -Daudacity_use_vorbis=system \
    -Daudacity_use_lv2=local \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="${pkgdir}" -C build install

  install -Dm644 ${srcdir}/build/bin/Release/plug-ins/*.ny -t "${pkgdir}/usr/share/${_realpkgname}/plug-ins"
  install -Dm644 ${srcdir}/build/bin/Release/nyquist/*.lsp -t "${pkgdir}/usr/share/${_realpkgname}/nyquist"

  install -Dm644 "${srcdir}/${_realpkgname}-${pkgver}/LICENSE.txt" -t "${pkgdir}/usr/share/licenses/$pkgname"
}