# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on aspell-en

_pkgname='aspell'
_pkglang='hr'
_srclang="${_pkglang}"
_srcsv=''
pkgname="${_pkgname}-i18n-dict-${_pkglang}"
# Example: _srcname='aspell6-en'
_srcname="${_pkgname}${_srcsv}-${_srclang}"
pkgver='0.51.0'
_srcver='0.51-0'
pkgrel='2'
pkgdesc='Croatian dictionary for Aspell'
arch=('i686' 'x86_64')
url='https://ftp.gnu.org/gnu/aspell/dict/0index.html'
license=('LGPL-2.1')
groups=("${_pkgname}-i18n-dict" "${_pkgname}-dict"
        "g${_pkgname}-i18n-dict" "g${_pkgname}-dict"
        "gnu${_pkgname}-i18n-dict" "gnu${_pkgname}-dict"
        "gnu-${_pkgname}-i18n-dict" "gnu-${_pkgname}-dict")
depends=('aspell')
provides=("${_pkgname}-dict-${_pkglang}"
          "g${pkgname}" "g${_pkgname}-dict-${_pkglang}"
          "gnu${pkgname}" "gnu${_pkgname}-dict-${_pkglang}"
          "gnu-${pkgname}" "gnu-${_pkgname}-dict-${_pkglang}"
          "${_pkgname}-${_pkglang}")
conflicts=("${_pkgname}-${_pkglang}")
replaces=("${_pkgname}-${_pkglang}")
_source=("https://ftp.gnu.org/gnu/${_pkgname}/dict/${_srclang}/")
source=("${_source[0]}/${_srcname}-${_srcver}.tar.bz2"
        "${_source[0]}/${_srcname}-${_srcver}.tar.bz2.sig")
sha512sums=('d6d891f3e55252fdbc5e0534c623cc42311c25cd1219351ce8a8160c3c3c49a6f219706e02f2c1c27174ef77c64e17f8cc25844befb17a43802b0a09ab42b1ad'
            'SKIP')
validpgpkeys=(# Denis Lackovic
              '6DBCD62A42564F2F6D2B3EA5E628E9881811E418')
unset _pkgname _pkglang _srclang _srcsv _source

build() {
  cd "${srcdir}/${_srcname}-${_srcver}"
  ./configure
  make 'V=1'
}

package() {
  cd "${srcdir}/${_srcname}-${_srcver}"
  make "DESTDIR=${pkgdir}" 'install'

  for i in 'COPYING' 'Copyright'; do
    install -Dm '644' "${i}" -t "${pkgdir}/usr/share/licenses/${pkgname}"
  done
  unset i _srcname _srcver
}