# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=asc
pkgver=2.6.1.0
_debver=$pkgver
_debrel=9
_pkgmusicver=1.3
pkgrel=3
pkgdesc="Advanced Strategic Command is a free and libre turn-based strategy game"
url='http://www.asc-hq.org/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('boost-libs' 'bzip2' 'expat' 'gcc-libs' 'freetype2' 'physfs' 'lua51'
         'libpng' 'sdl' 'sdl_image' 'sdl_mixer' 'sdl_sound' 'wxgtk2' 'libsigc++')
makedepends=('boost' 'quilt' 'zip')
groups=('games')
source=("${pkgname}-${pkgver}.tar.bz2::https://deb.debian.org/debian/pool/main/a/asc/asc_${pkgver}.orig.tar.bz2"
        "https://deb.debian.org/debian/pool/main/a/asc/asc_${_debver}-${_debrel}.debian.tar.xz"
        "${pkgname}-music-${_pkgmusicver}.tar.gz::https://deb.debian.org/debian/pool/main/a/asc-music/asc-music_${_pkgmusicver}.orig.tar.gz")
sha512sums=('9bf6c8ef44e4f8df32335d6fda3d755e74065cfa36cfab913c7f5990cea0d7f7215642e290a0aa0eaa98417a0f19a971d17fd4b464dbece9f60880bd32daee2e'
            '794bb68bf43122707476f6de0bd4b441e0476d0d46e8d81b5ba0878d0ed8b4dc9ec9af38cea1a3830e8aaae7fb1bcdd90b61a3f3055a609f936fb413353a8359'
            '918dc746c5739cb5c7406cc54d0a3fa20cdf2ba2d0a6f54442b85ce598c76e4696f76fb2b08cfc70aa080ae90ab1cd28981408addd32f522566dcf3d2034c6fc')
noextract=("${pkgname}-music-${_pkgmusicver}.tar.gz")

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/pkg-config-freetype.patch || true
    rm -v debian/patches/FTBFS-GCC10.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}

  export CFLAGS="-I/usr/include/freetype2"
  export CXXFLAGS="${CFLAGS}"
  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --with-data-dir=/usr/share/games/$pkgname
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -d "${pkgdir}/usr/share/games/$pkgname/music"
  tar -xzf "${srcdir}/${pkgname}-music-${_pkgmusicver}.tar.gz" --strip 1 \
      -C   "${pkgdir}/usr/share/games/$pkgname/music"

  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  install -Dm644 debian/$pkgname.desktop -t "$pkgdir"/usr/share/applications
  install -Dm644 debian/icons/$pkgname.png -t "$pkgdir"/usr/share/pixmaps
}