# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=antimicrox
pkgver=3.1.4
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="Graphical program used to map keyboard buttons and mouse controls to a gamepad"
arch=('i686' 'x86_64')
url='https://github.com/AntiMicroX/antimicroX'
license=('GPL-3')
depends=('desktop-file-utils' 'hicolor-icon-theme' 'libxtst' 'qt-x11extras' 'sdl2')
makedepends=('cmake' 'extra-cmake-modules' 'gettext-tiny' 'itstool' 'qt-tools' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/AntiMicroX/${pkgname/x/X}/archive/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/antimicro/antimicro_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('48a00fb20a17830483989a017784bd9a3b061a8d2caed2c942168b98fb762fac850560d93b84ef19e8e02c14b0241e5be375bdb17f2f75a5df06f24426d10505'
            '18b194abcb3ad914e7aa92c7a9f10845054c182c2c44c1f12af0867006f9b644f6315412cac424d5066d50e88a19cffc626828dd40c4618196f2075652e9d97b')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake \
    -S ${pkgname}-${pkgver} \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DAPPDATA=ON \
    -DWITH_UINPUT=ON \
    -DWITH_X11=ON \
    -DWITH_XTEST=ON
  make -C build
}

package() {
  make DESTDIR="${pkgdir}" -C build install

  cd "${srcdir}/${pkgname}-${pkgver}"
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}