# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=alttab
pkgver=1.7.1
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="Task switcher for minimalistic WMs or standalone X session"
url='https://github.com/sagb/alttab'
license=('GPL-3')
arch=('i686' 'x86_64')
depends=('libx11' 'libxmu' 'libxft' 'libxrandr' 'libpng' 'uthash' 'libxpm')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/a/alttab/alttab_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/alttab/alttab_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('d9f6c1d00be21e975521ebc39e800f00522f0d898512a7e3a406ae859890c553a1ae312a0947701085831aa5e62b5b9db859ae84af4b3e8f3370462634a5ab97'
            '3a9e847b19ae49d3413b91187eb475c088a476dc62bc49d971abba31b50495022bed3af98bf846ec579a7a13d198e1aaccfa4a07885ed05a601fc522b99a3a64')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}