# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=aalib
pkgver=1.4rc5
_pkgver=1.4.0
_debver=1.4p5
_debrel=48
pkgrel=14
pkgdesc="A portable ASCII art graphic library"
arch=('i686' 'x86_64')
url='https://aa-project.sourceforge.net/aalib/'
license=('LGPL-2')
depends=('gpm' 'libx11')
makedepends=('libxt' 'quilt')
source=("https://downloads.sourceforge.net/sourceforge/aa-project/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/aalib/aalib_${_debver}-${_debrel}.debian.tar.xz"
	"aclocal-fixes.patch")
sha512sums=('3e4506eccce3b81ccbbb79a4a1b90abd39e2259e6043fde90f70b9ca279bd4c37758a047167267b97c4ec92f64fb17c7c8f548114f0d0c6e78ddb9463b5f1299'
            '56d5ea459c0b82e44d3124b41d1251c3f314a33132cebec654998e42437aa5ed02074a9ba99aa1aefde4958d1900e10af0bdb5e378ba15b26116ee8165ae9f8c'
            'aa98b2226c2dd15c13561b28b5558ed459e9065c2339222df7c3002ea17a9b81711e6ff4f59d66ad817d96461dd8b5411c87b049306c875f295fdb8d0c9425c7')

prepare() {
  cd ${pkgname}-${_pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0008-Symbol-versioning.patch || true

    quilt push -av
  else
    patch -p0 -i "${srcdir}/aclocal-fixes.patch"
  fi
  autoreconf -vfi
}

build() {
  cd ${pkgname}-${_pkgver}
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --infodir=/usr/share/info
  make
}

package() {
  cd ${pkgname}-${_pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}