# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=zvbi
pkgver=0.2.35
_debver=0.2.35
_debrel=18
pkgrel=2
pkgdesc='VBI capture and decoding library'
url='http://zapping.sourceforge.net/cgi-bin/view/ZVBI/WebHome'
arch=('i686' 'x86_64')
depends=('libpng' 'libx11')
makedepends=('quilt')
license=('GPL-2')
source=("https://downloads.sourceforge.net/sourceforge/zapping/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/z/zvbi/zvbi_$_debver-$_debrel.debian.tar.xz")
sha512sums=('3d73eb0a7d05fdf1e3f8a74cc9d4fcb2a0287285904d59230c832f42b91afb072e96bda7e396ef07f268348061a51242925746db124bbb713cf56bdfabdada5d'
            'fe6fa70e60d1e88139a639f1ba70607560038ce252521c9777b5df0abf9b7e1d9d4830b6f89e15ed9e89053832666903cd35081de42f1d48ccb67c11ba602796')

prepare() {
  cd zvbi-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd zvbi-${pkgver}

  ./configure \
    --prefix='/usr'
  make
}

package() {
  cd zvbi-${pkgver}

  make DESTDIR="${pkgdir}" install

  for i in COPYING{,.LIB}; do
    install -Dm644 $i -t ${pkgdir}/usr/share/licenses/${pkgname}
  done
}

# vim: ts=2 sw=2 et: