# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=zuki-themes
pkgver=4.0
pkgrel=1
pkgdesc="Free and libre themes for different environments using GTK+"
arch=('any')
url='https://github.com/lassekongo83/zuki-themes'
license=('GPL-3')
depends=('gtk2-engine-murrine')
makedepends=('ninja' 'meson' 'sassc')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/lassekongo83/zuki-themes/archive/v${pkgver//_/-}.tar.gz")
sha512sums=('0640613de612821035c9ebdbbe8c03f2c500e0ab80369b87be61483c2fe38b2a38b4909c3525daff0c41dad2ee5da060c3b4d7a6ccb7cbd27d7154a131f3aef6')

build() {
  cd $pkgname-${pkgver//_/-}
  meson --prefix /usr --buildtype=plain build
  ninja -C build
}

package(){
  cd $pkgname-${pkgver//_/-}
  DESTDIR="$pkgdir" ninja -C build install

  # cleanup data we do not support
  rm -rf "$pkgdir/usr/share/themes/Zuki-shell"
  rm -rf "$pkgdir/usr/share/themes/Zukitre/"{gtk-4.0,xfwm4}
  rm -rf "$pkgdir/usr/share/themes/Zukitre-dark/"{gtk-4.0,xfwm4}
  rm -rf "$pkgdir/usr/share/themes/Zukitwo/"{gtk-4.0,xfwm4}
  rm -rf "$pkgdir/usr/share/themes/Zukitwo-dark/"{gtk-4.0,xfwm4}

  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}