# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=zathura
pkgver=0.5.2
pkgrel=3
pkgdesc="Minimalistic, free and libre document viewer"
url='https://pwmt.org/projects/zathura/'
arch=('i686' 'x86_64')
license=('zlib')
depends=('girara' 'sqlite' 'desktop-file-utils' 'file')
makedepends=('python-sphinx' 'meson' 'ninja' 'check' 'gettext-tiny')
optdepends=('zathura-djvu: DjVu support'
            'zathura-pdf-poppler: PDF support using Poppler'
            'zathura-pdf-mupdf: PDF support using MuPDF'
            'zathura-ps: PostScript support'
            'zathura-cb: Comic book support')
source=("${pkgname}-${pkgver}.tar.xz::https://pwmt.org/projects/zathura/download/${pkgname}-${pkgver}.tar.xz"
        "remove-appstreamglib.patch")
sha512sums=('3bf73d36d4e6c5192b28d5d8ce9940630e157072f43b4b6ba477bd0e599d0c26908e929e2cb707b516bafb287d0296b5eecdeba0f18f5271459738e516ce6385'
            'a8c1b4affc5002eca3d3286ffe79318ac77a399f5985643668e237415d963559ed0c89b23b24ae9d8450c91d6e62f315e2d695165a144ce1e4a23a1ce56937e2')

prepare() {
  cd "$pkgname-$pkgver"
  patch -Np1 -i ${srcdir}/remove-appstreamglib.patch
}

build() {
  cd "$pkgname-$pkgver"
  hyperbola-meson build \
    -D synctex=disabled

  cd build
  ninja
}

package() {
  cd "$pkgname-$pkgver/build"
  DESTDIR="$pkgdir" ninja install

  # remove unneeded parts, we do not support
  rm -rf "$pkgdir"/usr/share/{dbus-1,fish}

  install -D -m664 $srcdir/$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}