# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=yelp-tools
pkgver=3.38.0
_debver=3.38.0
_debrel=1
pkgrel=1
pkgdesc='Collection of tools for building and converting documentation'
url='https://gitlab.gnome.org/GNOME/yelp-tools'
arch=('any')
depends=('yelp-xsl' 'libxslt' 'libxml2' 'itstool' 'docbook-xsl' 'mallard-ducktype')
makedepends=('quilt')
license=('GPL-2')
source=("https://deb.debian.org/debian/pool/main/y/yelp-tools/yelp-tools_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/y/yelp-tools/yelp-tools_$_debver-$_debrel.debian.tar.xz")
sha512sums=('2042e37f8efbe9974f5a507910393b837a0b9154beb918a5e8d145205fb519c8244bb405cf328ff5014287086be5b6d33ad631951bd0e950c2ad9efc60065d59'
            '170a700985227c4559d95c89b0fbe78ab17ca844c0a01424fc19810eb2d00fc9b8e19224e642e095e3a654cb633a19fff521678535420358467fd409e7668a18')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING.GPL -t "${pkgdir}/usr/share/licenses/$pkgname"
}