# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=yasm
pkgver=1.3.0
_debver=1.3.0
_debrel=2
pkgrel=2
pkgdesc="A rewrite of NASM to allow for multiple syntax supported (NASM, TASM, GAS, etc.)"
arch=('i686' 'x86_64')
url="http://www.tortall.net/projects/yasm/"
license=('LGPL-2')
depends=('glibc')
makedepends=('quilt')
options=('staticlibs')
source=(http://www.tortall.net/projects/yasm/releases/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/y/yasm/yasm_$_debver-$_debrel.debian.tar.xz)
sha512sums=('572d3b45568b10f58e48f1188c2d6bcbdd16429c8afaccc8c6d37859b45635e106885d679e41d0bee78c23822108c7ae75aa7475eed5ba58057e0a6fe1b68645'
            '14df8de5cc7752c7ab250d3fe4c0c93a0b0be9e3685c111eebe8a8a675a5cdef6c1efd8bf9c9144ef84234b6ca5072c2cec3cb18c18bbbbf5435059cd590e700')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  install -Dm644 GNU_LGPL-2.0 "${pkgdir}/usr/share/licenses/${pkgname}/GNU_LGPL-2.0"
}