# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=yash
pkgver=2.52
pkgrel=2
pkgdesc="Yet Another SHell is a POSIX-compliant command line shell"
arch=('i686' 'x86_64')
url='https://magicant.github.io/yash/'
license=('GPL-2')
depends=('ncurses')
makedepends=('asciidoc' 'ed')
install=${pkgname}.install
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/y/yash/yash_${pkgver}.orig.tar.gz"
        "remove-mofiles.patch")
sha512sums=('f773203f4b40bd2ffa949669b2a40b8f9219dbef9cd781622ef63d85d04f7bd8dff7c00f2b32a48838ef8865c3e56536c506bbabd2a9015f277924e0539df8d1'
            '56e7975fad00b867432e197f34d02664e203800d41be19f08a21b52f466668a8aa4d62e67c4f7f936fdf60a0b8f47b30d2c678a9b23215955da1c0f311f37ba7')

prepare() {
  cd "${pkgname}-${pkgver}"

  rm -rf ./po
  patch -Np1 -i ${srcdir}/remove-mofiles.patch
}

build() {
  cd "${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --enable-array \
    --enable-dirstack \
    --enable-double-bracket \
    --enable-help \
    --enable-history \
    --enable-lineedit \
    --enable-nls \
    --enable-printf \
    --enable-socket \
    --enable-test \
    --enable-ulimit
  make
}

package() {
  cd "${pkgname}-${pkgver}"

  make install DESTDIR="${pkgdir}"
  install -Dm0644 doc/*.{css,html} -t "${pkgdir}/usr/share/doc/${pkgname}/"
  install -Dm0644 doc/ja/*.{css,html} -t "${pkgdir}/usr/share/doc/${pkgname}/ja/"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}