# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=yaml-cpp
pkgver=0.6.3
pkgrel=2
pkgdesc="YAML parser and emitter in C++, written around the YAML 1.2 spec"
url="https://github.com/jbeder/yaml-cpp"
arch=('i686' 'x86_64')
license=('Expat')
depends=('gcc-libs')
makedepends=('cmake')
source=("https://github.com/jbeder/$pkgname/archive/$pkgname-${pkgver}.tar.gz")
sha512sums=('68b9ce987cabc1dec79382f922de20cc2c222cb9c090ecb93dc686b048da5c917facf4fce6d8f72feea44b61e5a6770ed3b0c199c4cd4e6bde5b6245c09f8e49')

build() {
  cmake -B build -S ${pkgname}-${pkgname}-${pkgver} \
    -D BUILD_SHARED_LIBS=ON \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D YAML_BUILD_SHARED_LIBS=ON
  make VERBOSE=1 -C build
}

check() {
  make VERBOSE=1 -C build test
  build/test/run-tests
}

package() {
  make DESTDIR="$pkgdir" -C build install

  cd "${pkgname}-${pkgname}-${pkgver}"
  install -vDm 644 {CONTRIBUTING,README}.md \
    -t "$pkgdir/usr/share/doc/$pkgname"
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}