# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xterm
pkgver=362
_debver=362
_debrel=1
pkgrel=1
pkgdesc="X Terminal Emulator"
arch=('i686' 'x86_64')
url="https://invisible-island.net/xterm/"
license=('X11')
depends=('libxft' 'libxaw' 'ncurses' 'xenocara-luit' 'xenocara-xbitmaps' 'libutempter' 'libxkbfile')
makedepends=('quilt')
source=(https://invisible-mirror.net/archives/${pkgname}/${pkgname}-${pkgver}.tgz{,.asc}
        https://deb.debian.org/debian/pool/main/x/xterm/xterm_$_debver-$_debrel.debian.tar.xz)
sha512sums=('fddfa689fe948245964b347f27c8c66b28eee82cb78062f0e296053a5db9a20f74786b34058512b109064628992db94e87bc12c79f2db4a50acb79e408173168'
            'SKIP'
            '939ec913ecf06fcfd52bca594024e0339d3bfa1f0cd53428dd49a772d3f859dd46eaa191f7b58019518593c5d100ee7bc1afa32802fed4d4c53c2183bf4f5b0d')
validpgpkeys=('C52048C0C0748FEE227D47A2702353E0F7E48EDB') # "Thomas Dickey <dickey@invisible-island.net>"

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/900_debian_xterm.diff || true
    rm -v debian/patches/902_windowops.diff || true
    rm -v debian/patches/904_fontops.diff || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
      --libdir=/etc \
      --mandir=/usr/share/man \
      --with-app-defaults=/usr/share/X11/app-defaults/ \
      --with-x \
      --disable-full-tgetent \
      --disable-imake \
      --enable-ansi-color \
      --enable-88-color \
      --enable-256-color \
      --enable-broken-osc \
      --enable-broken-st \
      --enable-load-vt-fonts \
      --enable-i18n \
      --enable-wide-chars \
      --enable-doublechars \
      --enable-warnings \
      --enable-tcap-query \
      --enable-logging \
      --enable-dabbrev \
      --enable-freetype \
      --enable-luit \
      --enable-mini-luit \
      --enable-narrowproto \
      --enable-exec-xterm \
      --enable-sixel-graphics \
      --enable-regis-graphics \
      --with-tty-group=tty \
      --with-utempter
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  chmod 0755 "${pkgdir}/usr/bin/xterm"

  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  install -m755 -d ${pkgdir}/usr/share/applications
  install -m644 ${srcdir}/${pkgname}-${pkgver}/{xterm,uxterm}.desktop ${pkgdir}/usr/share/applications/
}