# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xpad
pkgver=4.8.0
pkgrel=1
pkgdesc="Stickies-like notes program"
arch=('i686' 'x86_64')
depends=('gtk' 'libsm' 'librsvg-legacy' 'gtksourceview3')
makedepends=('intltool' 'gettext-tiny')
url='https://launchpad.net/xpad'
license=('GPL-2')
source=("https://launchpad.net/${pkgname}/trunk/${pkgver}/+download/${pkgname}-${pkgver}.tar.bz2"
        "fix-build.patch")
sha512sums=('286afe23ace31e983c7db44231600dfb5c9ef2faa82b5560df3e1ab0b64deba2bee52cf805b728b12705b899ac3f3bc9715bc77d0d7e01dd692b9802edd358fe'
            '6074b896b6efed02b4bb4baf2bfdd40486b66f260a68c44510291d78c81969ac240239cccbccef19c1531ca7953a75472fcd5bf73ee2cb99d89335dfa73218ed')

prepare() {
  cd "$srcdir"/$pkgname-$pkgver
  patch -Np1 -i ${srcdir}/fix-build.patch
  autoreconf -vfi
}

build() {
  cd "$srcdir"/$pkgname-$pkgver
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver
  make DESTDIR="$pkgdir" install helpdir=/usr/share/xpad/help
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}