# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xrestop package

pkgname=xorg-xrestop
pkgver=0.4
_debver=0.4
_debrel=10
pkgrel=2
pkgdesc="Uses the X-Resource extension to provide 'top' like statistics"
arch=('i686' 'x86_64')
url="https://freedesktop.org/wiki/Software/xrestop/"
license=('GPL-2')
depends=('libxres' 'ncurses')
makedepends=('quilt')
provides=('xrestop')
conflicts=('xrestop')
replaces=('xrestop')
source=(https://downloads.yoctoproject.org/releases/xrestop/xrestop-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/x/xrestop/xrestop_$_debver-$_debrel.debian.tar.xz)
sha512sums=('eb7bf2f3ab7b73708c96d56fd466cb362d711242dd46992fa3e693af2d26995e9baa91075eb445ef227e1342deec5e0e22b37139e80399e4051c9f5cad8fd9b6'
            'b6103bbd73aa8f36beb184b191b7b78cb902cd849d3e22bdb67f48a9f85123b25629a4fac50b68635ffefe45317141f08804fa567f8cf5a606fe19a84b651186')

prepare() {
  cd "xrestop-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "xrestop-$pkgver"
  ./configure --prefix=/usr --mandir=/usr/share/man
  make
}

package() {
  cd "xrestop-$pkgver"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}