# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xf86-video-sisusb package

pkgname=xorg-video-sisusb
pkgver=0.9.7
pkgrel=4
pkgdesc="X.Org SiS USB video driver"
arch=(i686 x86_64)
url="https://xorg.freedesktop.org/"
license=('Modified-BSD')
depends=('glibc')
makedepends=('xenocara-server-devel' 'X-ABI-VIDEODRV_VERSION=24.0' 'xenocara-util-macros')
provides=('xf86-video-sisusb')
conflicts=('xf86-video-sisusb' 'xenocara-server<1.20' 'X-ABI-VIDEODRV_VERSION<24' 'X-ABI-VIDEODRV_VERSION>=25')
replaces=('xf86-video-sisusb')
groups=('xenocara-video-drivers' 'xenocara-video' 'xenocara-drivers'
        'xorg-video-drivers' 'xorg-video' 'xorg-drivers')
source=(https://xorg.freedesktop.org/releases/individual/driver/xf86-video-sisusb-$pkgver.tar.bz2)
sha512sums=('6edaf54bad80a261fa22606cad6619992e04560e132b3e68be30c80ebf2e599bc157118e725f67c5d96adc09ed036cc0c78ae0e0ce926708726f953a2fc34f02')

prepare() {
  cd "xf86-video-sisusb-$pkgver"
  autoreconf -vfi
}

build() {
  cd "xf86-video-sisusb-$pkgver"

  # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  # With them, module fail to load with undefined symbol.
  # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  export CFLAGS=${CFLAGS/-fno-plt}
  export CXXFLAGS=${CXXFLAGS/-fno-plt}
  export LDFLAGS=${LDFLAGS/,-z,now}

  ./configure --prefix=/usr
  make
}

package() {
  cd "xf86-video-sisusb-$pkgver"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}