# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xmoto
pkgver=0.6.2
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="A challenging, free and libre 2D motocross platform game, where physics have an important role"
arch=('i686' 'x86_64')
url='https://xmoto.tuxfamily.org'
license=('GPL-2' 'LGPL-2.1' 'Modified-BSD' 'Simplified-BSD' 'Original-BSD' 'Expat')
depends=('libjpeg-turbo' 'libpng' 'lua' 'ode' 'curl' 'sqlite' 'glu' 'libxdg-basedir' 'libxml2'
         'sdl2_mixer' 'sdl2_net' 'sdl2_ttf')
makedepends=('intltool' 'cmake' 'ninja' 'quilt')
groups=('games')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/x/xmoto/xmoto_${pkgver}+repack.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/x/xmoto/xmoto_${_debver}+repack-${_debrel}.debian.tar.xz"
        "installation-directories.patch")
sha512sums=('abecf9c194e56bd4ddf2335de88aacc6ba016a3f49d0f96959a4553f6490c9e432ce2ec9fd423d71c6f2b15d4db173ef4e6fa3b187db1c0be05a36c4900c868d'
            '4ee2ba47719ebf9a160f6af0b79e2c0f4665a1d8bfac8a6d42baf8c14eed757a44ad4f5fd1f2682a10e4a23d47946dca89930b22da720997c0cb660c62a58dec'
            'ed1ce53d3c99b3a64137afcba2c34f429131e9cd0349db61b7feac86b5d4dc6fd6fd9db2f54ba5d9dfce8d1dbac1986ab2992b7979c0dda85856e80048a45c60')

prepare() {
  mkdir -p build

  cd ${pkgname}-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/system-chipmunk.patch || true
    rm -v debian/patches/installation-directories.patch || true

    quilt push -av
  fi

  # fixing data-directories being FHS-compliant
  patch -Np1 -i "${srcdir}/installation-directories.patch"
  sed -i "s|DESTINATION bin|DESTINATION games|g" src/CMakeLists.txt
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX=/usr
  ninja
  ninja xmoto_pack
}

package() {
  cd build
  DESTDIR="${pkgdir}" ninja install

  # cleaning data
  rm -rf "${pkgdir}/usr/share/xmoto"

  # install man page
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/doc/xmoto.6" -t "${pkgdir}//usr/share/man/man6"

  # install license
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/COPYING" "${srcdir}/${pkgname}-${pkgver}/debian/copyright" -t "${pkgdir}/usr/share/licenses/$pkgname"
}